Удалите значки "Основной исполняемый модуль" в системном трее на Windows 10 Professional x64

Question

У меня есть эти две иконки в системном трее. У меня Win10 Pro x64. Почему они там? Как я могу избавиться от них, кроме просто не показывать их?

Answer 1

Самое простое решение для очистки двоичных данных: IconStreams и PastIconsStream, расположенные в HKEY_CURRENT_USER\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify

1. Запустите скрипт .bat ниже
2. Закройте и сохраните все, над чем вы работаете, прежде чем продолжить. Следующие шаги будут включать в себя убийство проводника и перезагрузку ПК.
3. Запустите файл .bat.
4. Если будет предложено, нажмите / нажмите « Выполнить» для подтверждения. При желании вы можете разблокировать файл .bat, чтобы больше не получать подсказку «Выполнить (открыть файл - предупреждение системы безопасности)».
5. Следуйте инструкциям в командной строке, чтобы сбросить значки области уведомлений. Если вы не перезагружаете компьютер сейчас, вам потребуется позже, чтобы завершить сброс значков области уведомлений. (см. скриншоты ниже)

Источник: Как сбросить значки области уведомлений в Windows 10

Reset_Notification_Area_Icons_Cache

:: Created by: Shawn Brink
:: http://www.tenforums.com
:: Tutorial: http://www.tenforums.com/tutorials/5662-notification-area-icons-reset-windows-10-a.html


@echo off

set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream


echo.
echo The Explorer process must be temporarily killed before deleting your notification area icons cache. 
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause


echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.

:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart

:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream

:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"


:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your notification area icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes


:no
echo.
echo.
echo Restarting explorer.... 
echo.
echo Please remember to restart the PC later to finish resetting your notification area icons.
echo.
start explorer.exe
pause
exit /B

:yes
shutdown /r /f /t 00