Как установить звуковое оповещение о 100% заряде батареи?

Question

Мы можем установить звуковое оповещение о низком / критическом заряде батареи, но я не знаю, как настроить звуковое оповещение о полном заряде батареи. Есть ли способ сделать это?

РЕДАКТИРОВАТЬ: Я согласен с тем, что не все ноутбуки заряжаются до 100%, тогда мой вопрос перефразирует от 100% до 95%, или, возможно, получить уведомление в какой-то определенный возраст% ...

Answer 1

Я не могу установить полное звуковое оповещение батареи, есть ли способ сделать это?

Используйте следующий пакетный файл (Battery.cmd):

@echo off
setlocal EnableDelayedExpansion
rem set threshold value
set _threshold=95
:start
rem get the battery charge
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=1" %%i in (`wmic Path Win32_Battery Get EstimatedChargeRemaining ^| findstr /r /v "^$"`) do (
  set _charge=%%i
  echo !_charge!
  if !_charge! geq !_threshold! (
    echo charge reached
    goto :done
    ) else (
    rem wait for 10 minutes then try again
    timeout /t 600 /nobreak
    goto :start
    )
  )
:done
endlocal

Заметки:

• Этот пакетный файл отслеживает текущий процент заряда батареи и печатает "достигнутый заряд", когда заряд достигает определенного пользователем порогового значения (в данном случае 95%). Пакетный файл затем заканчивается. Если заряд падает ниже порогового значения, пользователь должен снова запустить пакетный файл вручную.
• Установите _threshold как требуется.
• Замените команду echo charge reached командой воспроизведения выбранного звука.
  • Если вы хотите создать пользовательское событие (в журнале событий) вместо воспроизведения звука, см. Мой идентификатор события Windows для ответа об изменении уровня заряда батареи.
• Измените задержку timeout в соответствии с вашей ситуацией.

---

Дальнейшее чтение

• Индекс AZ командной строки Windows CMD - Отличный справочник по всем вопросам, связанным с командной строкой Windows.

• wmic - команда инструментария управления Windows.