Как я могу создать задание cron, которое будет запускать задание каждые три недели?

Question

У меня есть задача, которую нужно выполнить в моем графике проекта (3 недели).

Я могу настроить cron, чтобы делать это каждую неделю или (например) на 3-й неделе каждого месяца - но не могу найти способ делать это каждые три недели.

Я мог взломать сценарий для создания временных файлов (или аналогичных), чтобы он мог работать, это был третий раз, когда он был запущен - но это решение пахнет.

Можно ли это сделать чистым способом?

Answer 1

Файл crontab позволяет только указать:

minute (0-59)
hour (0-23)
day of the month (1-31)
month of the year (1-12)
day of the week (0-6 with 0=Sunday)

Поэтому невозможно указать, какие недели должны применяться.

Написание сценария оболочки может быть лучшим вариантом.
Вы можете получить номер недели в shell-скрипте, используя

date +%U

или же

date +%V

в зависимости от того, хотите ли вы, чтобы ваши недели начинались в воскресенье или в понедельник.
Так что вы могли бы использовать

week=$(date +%V)
check=$(( ($week - 1) % 3 ))

И $ check будет 0 в 1-ю, 4-ю, 7-ю, ... недели года.

Answer 2

Благодаря более ранним ответам были указаны параметры эпохи для даты -e или форматирования как% s

Хотя немного болезненно ((date +%s) / 86400) дает дни с эпохи.

Опираясь на еженедельное выполнение задания в одно и то же время, легко проверить это по определенному дню трехнедельного периода (например, $epoch_day%21 == 13 )

В моем случае это нормально, так как это одноразовая задача. Если он пропущен в определенный день, то нет необходимости использовать следующую возможность.

Answer 3

Если вы можете сохранить файл метки времени между запусками, вы можете проверить его дату, а не полагаться только на текущую дату.

Если ваша команда find поддерживает дробные значения для -mtime (или имеет -mmin) (в GNU find есть и то, и другое, POSIX, похоже, не требуется), вы можете «задушить» задания cron с помощью find и touch.

Или, если у вас есть команда stat, которая поддерживает отображение дат файлов как «секунд с начала эпохи» (например, stat из Gnu coreutils, а также других реализаций), вы можете сделать свое собственное сравнение, используя date, stat и операторы сравнения оболочки (вдоль с прикосновением, чтобы обновить файл метки времени). Вы также можете использовать ls вместо stat, если он может выполнять форматирование (например, ls из GNU fileutils).

Ниже приведена программа на Perl (я назвал ее n-hours-ago), которая обновляет файл отметки времени и успешно завершает свою работу, если исходная отметка времени была достаточно старой. Текст его использования показывает, как использовать его в записи crontab для регулирования работы cron. В нем также описываются корректировки для «летнего времени» и как обрабатывать «поздние» временные метки из предыдущих прогонов.

#!/usr/bin/perl
use warnings;
use strict;
sub usage {
    printf STDERR <<EOU, $0;
usage: %s <hours> <file>

    If entry at pathname <file> was modified at least <hours> hours
    ago, update its modification time and exit with an exit code of
    0. Otherwise exit with a non-zero exit code.

    This command can be used to throttle crontab entries to periods
    that are not directly supported by cron.

        34 2 * * * /path/to/n-hours-ago 502.9 /path/to/timestamp && command

    If the period between checks is more than one "day", you might
    want to decrease your <hours> by 1 to account for short "days"
    due "daylight savings". As long as you only attempt to run it at
    most once an hour the adjustment will not affect your schedule.

    If there is a chance that the last successful run might have
    been launched later "than usual" (maybe due to high system
    load), you might want to decrease your <hours> a bit more.
    Subtract 0.1 to account for up to 6m delay. Subtract 0.02 to
    account for up to 1m12s delay. If you want "every other day" you
    might use <hours> of 47.9 or 47.98 instead of 48.

    You will want to combine the two reductions to accomodate the
    situation where the previous successful run was delayed a bit,
    it occured before a "jump forward" event, and the current date
    is after the "jump forward" event.

EOU
}

if (@ARGV != 2) { usage; die "incorrect number of arguments" }
my $hours = shift;
my $file = shift;

if (-e $file) {
    exit 1 if ((-M $file) * 24 < $hours);
} else {
    open my $fh, '>', $file or die "unable to create $file";
    close $fh;
}
utime undef, undef, $file or die "unable to update timestamp of $file";
exit 0;