Как я могу создать "Cross-Join" в Excel?

Question

У меня есть 2 листа в Excel, каждый с 10 рядами. Существует ли какая-то формула / макрос для перекрестного соединения в Excel, которая позволяет мне создавать 3-й лист со всеми рядами перекрестных соединений (всего 100 строк).

Answer 1

Если использование OLEDB не является опцией ниже, можно использовать функцию для создания перекрестного произведения.

Option Base 1

Function Cross_Product_range(r1 As Range, r2 As Range) As Variant
    Cross_Product_range = Cross_Product_array(r1.Value, r2.Value)
End Function

Function Cross_Product_array(a1 As Variant, a2 As Variant) As Variant
    On Error GoTo ErrorHandler
    Dim TempArray(), k, m
    ReDim TempArray(UBound(a1) * UBound(a2), UBound(a1, 2) + UBound(a2, 2))
    k = 1
    For i = 1 To UBound(a1)
        For j = 1 To UBound(a2)
            m = 1
            For u = 1 To UBound(a1, 2)
                TempArray(k, m) = a1(i, u)
                m = m + 1
            Next
            For u = 1 To UBound(a2, 2)
                TempArray(k, m) = a2(j, u)
                m = m + 1
            Next
            k = k + 1
        Next
    Next
    Cross_Product_array = TempArray
    Exit Function
    ErrorHandler:
    Debug.Print Err
End Function

После того, как вышеупомянутая функция добавлена в модуль vba, для получения перекрестного произведения A1:B5 и C1:D5 выберите целевые ячейки (скажем, E1:H25) и введите формулу и используйте ctrl + shift + enter

=Cross_Product_range(A1:B5,C1:D5)